ESP8266簡易WIFI天氣時鐘

本篇介紹了如何使用ESP8266，通過WIFI連網獲取網絡天氣和網絡時間，然后借助U8g2庫，在OLED上顯示當前時間和天氣信息。

1 HTTP獲取網絡天氣

連網獲取網絡天氣，一般需要通過http的方式，從天氣信息提供商的網絡地址獲取天氣信息。

1.1 注冊開發者key

這里以心知天氣為例，需要先注冊一個開發者賬號，然后獲取自己的私鑰，也就是等下要用到的key。

然后可以先在瀏覽器中輸入如下鏈接，注意要將自己的key替換進去，然后就可以測試一下天氣信息的獲取情況。

https://api.seniverse.com/v3/weather/now.json?key=替換為你的私鑰&location=HangZhou&language=en&unit=c

如下即為獲取的天氣信息，是json格式的：

1.2 http請求基本原理

上面先通過瀏覽器的方式獲取到了天氣信息，而ESP8266沒有瀏覽器功能，需要編寫代碼實現http數據請求。

在編寫代碼之前，需要先了解一下基礎的http請求原理。

url全稱是資源描述符，一個url地址，用于描述一個網絡上的資源，而http中的get、post、put、delete就對于著這個資源的查、改、增、刪4個操作，get一般用于獲取/查詢資源信息。

url的格式： 【協議】：//【主機名(或者叫域名)】【：端口號（可選）】/【文件路徑】/【文件名】

例如：https://api.seniverse.com/v3/weather/now.json?key=替換為你的私鑰&location=HangZhou&language=en&unit=c

協議：https

域名：api.seniverse.com

客戶端發送一個HTTP請求到服務器的請求消息包括以下格式：請求行（request line）、請求頭部（header）、空行和請求數據四個部分組成，下圖給出了請求報文的一般格式。

服務器HTTP響應也由四個部分組成，分別是：狀態行、消息報頭、空行和響應正文。

根據http協議，可以編寫ESP8266進行http請求的代碼：

const char* host = "api.seniverse.com";     // 將要連接的服務器地址  
const int httpPort = 80;                    // 將要連接的服務器端口      
 
// 心知天氣HTTP請求所需信息
String reqUserKey = "xxxxxxxxxxxxxxxxx";   // 私鑰
String reqLocation = "HangZhou";           // 城市
String reqUnit = "c";                      // 攝氏/華氏
 
// 建立心知天氣API當前天氣請求資源地址
String reqRes = "/v3/weather/now.json?key=" + reqUserKey +
    + "&location=" + reqLocation + 
    "&language=en&unit=" +reqUnit;

// 建立http請求信息
// 請求方法(GET)+空格+URL+空格+協議(HTTP/1.1)+回車+換行+
// 頭部字段(Host)+冒號+值(服務器地址)+回車+換行+
// 頭部字段(Connection)+冒號+值(close)+回車+換行+回車+換行
String httpRequest = String("GET ") + reqRes + " HTTP/1.1\r\n" + 
    "Host: " + host + "\r\n" + 
    "Connection: close\r\n\r\n";

WiFiClient client;
// 嘗試連接服務器
if (client.connect(host, 80))
{
    // 向服務器發送http請求信息
    client.print(httpRequest);
    Serial.println("Sending request: ");
    Serial.println(httpRequest);  

    // 獲取并顯示服務器響應狀態行 
    String status_response = client.readStringUntil('\n');
    Serial.print("status_response: ");
    Serial.println(status_response);

    // 使用find跳過HTTP響應頭
    if (client.find("\r\n\r\n")) 
    {
        Serial.println("Found Header End. Start Parsing.");
    }

    // 利用ArduinoJson庫解析心知天氣響應信息
    parseInfo(client); 
} 

1.3 json數據解析

http請求獲取到的天氣數據是json格式的（關于json的介紹可參考：），需要對數據進行解析，獲取到具體的天氣和溫度等數據。

可以將獲取的json原始數據打印出來，方便確認程序是否獲取到的天氣數據。

具體代碼如下：

void parseInfo(WiFiClient client)
{
  const size_t capacity = JSON_ARRAY_SIZE(1) + JSON_OBJECT_SIZE(1) + 2 * JSON_OBJECT_SIZE(3) + JSON_OBJECT_SIZE(6) + 230;
  DynamicJsonDocument doc(capacity);
  deserializeJson(doc, client);
  Serial.println(doc.as());

  JsonObject result0 = doc["results"][0];
  JsonObject result0_now = result0["now"];

  // 通過串口監視器顯示以上信息
  g_strWeather = result0_now["text"].as();// "Sunny"
  g_iCode = result0_now["code"].as();// "0"
  g_iTemperature = result0_now["temperature"].as();// "32"
  g_strUpdateTime = result0["last_update"].as();// "2020-06-02T14:40:00+08:00"

  Serial.println(F("======Weahter Now======="));
  Serial.print(F("Weather Now: "));
  Serial.print(g_strWeather);
  Serial.print(F(" -> "));
  Serial.println(g_iCode);
  Serial.print(F("Temperature: "));
  Serial.println(g_iTemperature);
  Serial.print(F("Last Update: "));
  Serial.println(g_strUpdateTime);
  Serial.println(F("========================"));
}

原始json格式的天氣數據和解析后的天氣和溫度數據如下：

天氣現象代碼對照表

解析到的天氣數據，除了英文形式的天氣信息(text)，還有一個對應的天氣碼(code)，如上圖的Cloudy對應的天氣碼是4。通過天氣碼，也可以轉換為天氣。天氣碼的對照表可參考心知天氣文檔：https://docs.seniverse.com/api/start/code.html

簡化起見，這里只使用常用的4種天氣。

2 NTP網絡時間

NTP(Network Time Protocol) 是網絡時間協議，它是用來同步網絡中各個計算機時間的協議。

ESP8266可以連網，那就也可以通過獲取網絡時間來得到當前的時間：

time_t getNtpTime()
{
    IPAddress ntpServerIP; // NTP服務器的地址
 
    while(Udp.parsePacket() > 0); // 丟棄以前接收的任何數據包
    Serial.println("Transmit NTP Request");
    // 從池中獲取隨機服務器
    WiFi.hostByName(ntpServerName, ntpServerIP);
    Serial.print(ntpServerName);
    Serial.print(": ");
    Serial.println(ntpServerIP);
    sendNTPpacket(ntpServerIP);
    uint32_t beginWait = millis();
    while (millis() - beginWait < 1500)
    {
        int size = Udp.parsePacket();
        if (size >= NTP_PACKET_SIZE)
        {
            Serial.println("Receive NTP Response");
            isNTPConnected = true;
            Udp.read(packetBuffer, NTP_PACKET_SIZE); // 將數據包讀取到緩沖區
            unsigned long secsSince1900;
            // 將從位置40開始的四個字節轉換為長整型，只取前32位整數部分
            secsSince1900 = (unsigned long)packetBuffer[40] << 24;
            secsSince1900 |= (unsigned long)packetBuffer[41] << 16;
            secsSince1900 |= (unsigned long)packetBuffer[42] << 8;
            secsSince1900 |= (unsigned long)packetBuffer[43];
            Serial.println(secsSince1900);
            Serial.println(secsSince1900 - 2208988800UL + timeZone * SECS_PER_HOUR);
            return secsSince1900 - 2208988800UL + timeZone * SECS_PER_HOUR;
        }
    }
    Serial.println("No NTP Response :-("); //無NTP響應
    isNTPConnected = false;
    return 0; //如果未得到時間則返回0
}

3 OLED顯示頁面設計

獲取到天氣信息和時間后，需要將這些信息顯示出來。

這里使用0.96寸OLED顯示屏來顯示，借助U8g2庫，顯示文字與天氣圖標（U8g2庫的使用，可參考：）。

具體的顯示代碼如下：

void testShowTimeAndWeather(rtc_time_t &now_time, weather_info_t &weather_info)
{
  u8g2.clearBuffer();
  int tm_year = now_time.tm_year;
  int tm_month = now_time.tm_mon;
  int tm_day = now_time.tm_mday;
  int tm_hour = now_time.tm_hour;
  int tm_minute = now_time.tm_min;
  int tm_sec = now_time.tm_sec;
  int tm_week = now_time.tm_week;
  
  //時分
  char str_big_time[] = "";
  my_strcat(str_big_time, tm_hour);
  strcat(str_big_time,":");
  my_strcat(str_big_time, tm_minute);
  u8g2.setFont(u8g2_font_logisoso24_tf); 
  u8g2.drawStr(0, 30, str_big_time);

  //秒
  char str_small_sec[] = "";
  my_strcat(str_small_sec, tm_sec);
  u8g2.setFont(u8g2_font_wqy14_t_gb2312);
  u8g2.drawStr(73, 30, str_small_sec);

  //日期
  char str_date[] = "";
  char str_temp[6];
  itoa(tm_year,str_temp,10);
  strcat(str_date,str_temp);
  strcat(str_date,"-");
  my_strcat(str_date, tm_month);
  strcat(str_date,"-");
  my_strcat(str_date, tm_day);
  u8g2.drawStr(0, 47, str_date);
  
  u8g2.setCursor(0, 63);
  u8g2.print("星期");
  switch (tm_week)
  {
    case 1: u8g2.print("日"); break;
    case 2: u8g2.print("一"); break;
    case 3: u8g2.print("二"); break;
    case 4: u8g2.print("三"); break;
    case 5: u8g2.print("四"); break;
    case 6: u8g2.print("五"); break;
    case 7: u8g2.print("六"); break;
    default: break;
  }
  u8g2.setCursor(60, 63);
  u8g2.print("杭州");

  //分割線
  u8g2.drawLine(90, 0, 90, 63);
  
  //天氣
  if (weather_info.iconIdx<0 || weather_info.iconIdx>3) //沒有對應的天氣圖標
  {
    Serial.print("no icon for weather: ");
    Serial.println(weather_info.weather);
  }
  else
  {
    u8g2.setFont(u8g2_font_open_iconic_weather_4x_t );
    u8g2.drawStr(96, 34, icon_index[weather_info.iconIdx]);
  }
  char temperature_tmp[25];
  itoa(weather_info.temp, temperature_tmp, 10);
  strcat(temperature_tmp,"℃");
  u8g2.setFont(u8g2_font_wqy16_t_gb2312);
  u8g2.setCursor(96, 55);
  u8g2.print(temperature_tmp);
  
  u8g2.sendBuffer();
}

4 最終效果

5 總結

本篇介紹了http獲取網絡天氣的基本原理，并通過實踐，使用ESP8266連網獲取網絡天氣和網絡時間，借助U8g2庫，在OLED上顯示當前時間和天氣信息。