使用51單片機實現搶答器的設計資料和代碼說明

在知識比賽中， 特別是做搶答題目的時候， 在搶答過程中，為了知道哪一組或哪一位選手先答題，必須要設計一個系統來完成這個任務。如果在搶答中，靠視覺是很難判斷出哪組先答題。利用單片機系統來設計搶答器，使以上問題得以解決，即使兩組的搶答時間相差幾微秒，也可分辨出哪組優先答題。本文主要介紹了單片機搶答器設計及工作原理，以及它的實際用途。 ！ 系統工作原理本系統采用8051單片機作為核心。控制系統的四個模塊分別為：存儲模塊、顯示模塊、語音模塊、搶答開關模塊。該搶答器系統通過開關電路四個按鍵輸入搶答信號；利用語音芯片ISD1420 完成語音的錄放功能； 利用存儲程序； 利用一個數碼管來完成顯示功能。工作時，用按鍵通過開關電路輸入各路的搶答信號，經單片機的處理， 輸出控制信號， 控制數碼管和語音芯片工作。在數碼管上顯示哪一組先答題，并通過語音系統讀出 “第9組請答題”，從而實現整個搶答過程。系統的原理圖如下圖

下面這個單片機搶答器設計程序，大家測試一下

1、如果想調節搶答時間或答題時間，按“搶答時間調節”鍵或“答題時間調節”鍵進入調節狀態，此時會顯示現在設定的搶答時間或回答時間值，如想加一秒按一下“加1s”鍵，如果想減一秒按一下“-1s”鍵，時間LED上會顯示改變后的時間，調整范圍為0s~99s， 0s時再減1s會跳到99，99s時再加1s會變到0s。

2、主持人按“搶答開始”鍵，會有提示音，并立刻進入搶答倒計時（預設15s搶答時間），如有選手搶答，會有提示音，并會顯示其號數并立刻進入回答倒計時（預設10s搶答時間），不進行搶答查詢，所以只有第一個按搶答的選手有效。倒數時間到小于5s會每秒響一下提示音。

3、如倒計時期間，主持人想停止倒計時可以隨時按“停止”按鍵，系統會自動進入準備狀態，等待主持人按“搶答開始”進入下次搶答計時。

4、如果主持人未按“搶答開始”鍵，而有人按了搶答按鍵，犯規搶答，LED上不斷閃爍FF和犯規號數并響個不停，直到按下“停止” 鍵為止。

*******************************************************************************************

P1.0為開始搶答，P1.7為停止，p1.1-p1.6為六路搶答輸入 數碼管段選P0口，位選P2口，蜂鳴器輸出為P3.6口

*******************************************************************************************

;============

OK EQU 20H ;搶答開始標志位;將P1口與P2口互換，P3.0-P1.0，P3.1-P1.7

RING EQU 22H ;響鈴標志位

ORG 0000H

AJMP MAIN

ORG 0003H

AJMP INT0SUB

ORG 000BH

AJMP T0INT

ORG 0013H

AJMP INT1SUB

ORG 001BH

AJMP T1INT

ORG 0040H

;===============-

;單片機搶答器主程序設計

;================

MAIN： MOV R1，#0FH ;初設搶答時間為15s

MOV R2，#0AH ;初設答題時間為10s

MOV TMOD，#11H ;設置未定時器/模式1

MOV TH0，#0F0H

MOV TL0，#0FFH ;越高發聲頻率越高，越尖

MOV TH1，#3CH

MOV TL1，#0B0H ;50ms為一次溢出中斷

SETB EA

SETB ET0

SETB ET1

SETB EX0

SETB EX1 ;允許四個中斷，T0/T1/INT0/INT1

CLR OK

CLR RING

SETB TR1

SETB TR0 ;一開始就運行定時器，以開始顯示FFF.如果想重新計數，重置TH1/TL1就可以了

;=====查詢程序=====

START： MOV R5，#0BH

MOV R4，#0BH

MOV R3，#0BH

ACALL DISPLAY ;未開始搶答時候顯示FFF

JB P1.0，NEXT ;ddddddd

ACALL DELAY

JB P1.0，NEXT ;去抖動，如果“開始鍵”按下就向下執行，否者跳到非法搶答查詢

ACALL BARK ;按鍵發聲

MOV A，R1

MOV R6，A ;送R1-》R6，因為R1中保存了搶答時間

SETB OK ;搶答標志位，用于COUNT只程序中判斷是否查詢搶答

MOV R3，0AH ;搶答只顯示計時，滅號數

AJMP COUNT ;進入倒計時程序，“查詢有效搶答的程序”在COUNT里面

NEXT： JNB P1.1，FALSE1

JNB P1.2，FALSE2

JNB P1.3，FALSE3

JNB P1.4，FALSE4

JNB P1.5，FALSE5

JNB P1.6，FALSE6

AJMP START

;=====非法搶答處理程序=====

FALSE1： ACALL BARK ;按鍵發聲

MOV R3，#01H

AJMP ERROR

FALSE2： ACALL BARK

MOV R3，#02H

AJMP ERROR

FALSE3： ACALL BARK

MOV R3，#03H

AJMP ERROR

FALSE4： ACALL BARK

MOV R3，#04H

AJMP ERROR

FALSE5： ACALL BARK

MOV R3，#05H

AJMP ERROR

FALSE6： ACALL BARK

MOV R3，#06H

AJMP ERROR

;=====INT0（搶答時間R1調整程序）=====

INT0SUB:MOV A，R1

MOV B，#0AH

DIV AB

MOV R5，A

MOV R4，B

MOV R3，#0AH

ACALL DISPLAY ;先在兩個時間LED上顯示R1

JNB P3.4，INC0 ;P3.4為+1s鍵，如按下跳到INCO

JNB P3.5，DEC0 ;P3.5為-1s鍵，如按下跳到DECO

JNB P1.7，BACK0 ;P3.1為確定鍵，如按下跳到BACKO

AJMP INT0SUB

INC0： MOV A，R1

CJNE A，#63H，ADD0 ;如果不是99，R2加1，如果加到99了，R1就置0，重新加起。

MOV R1，#00H

ACALL DELAY1

AJMP INT0SUB

ADD0： INC R1

ACALL DELAY1

AJMP INT0SUB

DEC0： MOV A，R1

JZ SETR1 ;如果R1為0， R1就置99，

DEC R1

ACALL DELAY1

AJMP INT0SUB

SETR1： MOV R1，#63H

ACALL DELAY1

AJMP INT0SUB

BACK0： RETI

;=====INT1（回答時間R2調整程序）=====

INT1SUB：

MOV A，R2

MOV B，#0AH

DIV AB

MOV R5，A

MOV R4，B

MOV R3，#0AH

ACALL DISPLAY

JNB P3.4，INC1

JNB P3.5，DEC1

JNB P1.7，BACK1

AJMP INT1SUB

INC1： MOV A，R2

CJNE A，#63H，ADD1

MOV R2，#00H

ACALL DELAY1

AJMP INT1SUB

ADD1： INC R2

ACALL DELAY1

AJMP INT1SUB

DEC1： MOV A，R2

JZ SETR2

DEC R2

ACALL DELAY1

AJMP INT1SUB

SETR2： MOV R2，#63H

ACALL DELAY1

AJMP INT1SUB

BACK1： RETI

;=====倒計時程序（搶答倒計時和回答倒計時都跳到改程序）=====

COUNT： MOV R0，#00H ;重置定時器中斷次數

MOV TH1，#3CH

MOV TL1，#0B0H ;重置定時器

RECOUNT：

MOV A，R6 ;R6保存了倒計時的時間，之前先將搶答時間或回答時間給R6

MOV B，#0AH

DIV AB ;除十分出個位/十位

MOV 30H，A ;十位存于（30H）

MOV 31H，B ;個位存于（31H）

MOV R5，30H ;取十位

MOV R4，31H ;取個位

MOV A，R6

SUBB A，#07H

JNC LARGER ;大于5s跳到LARGER，小于等于5s會提醒

MOV A，R0

CJNE A，#0AH，FULL;1s中0.5s向下運行

CLR RING

AJMP CHECK

FULL： CJNE A，#14H，CHECK;下面系1s的情況，響并顯示號數并清R0，重新計

SETB RING

MOV A，R6

JZ QUIT ;計時完畢

MOV R0，#00H

DEC R6 ;一秒標志減1

AJMP CHECK

LARGER：

MOV A，R0

CJNE A，#14H，CHECK;如果1s向下運行，否者跳到查“停/顯示”

DEC R6 ;計時一秒R6自動減1

MOV R0，#00H

CHECK： JNB P1.7，QUIT ;如按下停止鍵退出

ACALL DISPLAY

JB OK，ACCOUT ;如果是搶答倒計時，如是則查詢搶答，否者跳過查詢繼續倒數（這里起到鎖搶答作用）

AJMP RECOUNT

ACCOUT:JNB P1.1，TRUE1

JNB P1.2，TRUE2

JNB P1.3，TRUE3

JNB P1.4，TRUE4

JNB P1.5，TRUE5

JNB P1.6，TRUE5

AJMP RECOUNT

QUIT： CLR OK ;如果按下了“停止鍵”執行的程序

CLR RING

AJMP START

;=====正常搶答處理程序=====

TRUE1： ACALL BARK ;按鍵發聲

MOV A，R2

MOV R6，A ;搶答時間R2送R6

MOV R3，#01H

CLR OK ;因為答題的計時不再查詢搶答，所以就鎖了搶答

AJMP COUNT

TRUE2： ACALL BARK;

MOV A，R2

MOV R6，A

MOV R3，#02H

CLR OK

AJMP COUNT

TRUE3： ACALL BARK;

MOV A，R2

MOV R6，A

MOV R3，#03H

CLR OK

AJMP COUNT

TRUE4： ACALL BARK;

MOV A，R2

MOV R6，A

MOV R3，#04H

CLR OK

AJMP COUNT

TRUE5： ACALL BARK;

MOV A，R2

MOV R6，A

MOV R3，#05H

CLR OK

AJMP COUNT

TRUE6： ACALL BARK;

MOV A，R2

MOV R6，A

MOV R3，#06H

CLR OK

AJMP COUNT

;=====犯規搶答程序=====

ERROR： MOV R0，#00H

MOV TH1，#3CH

MOV TL1，#0B0H

MOV 34H，R3 ;犯規號數暫存與（34H）

HERE： MOV A，R0

CJNE A，#0AH，FLASH ;0.5s向下運行-》滅并停響

CLR RING

MOV R3，#0AH

MOV R4，#0AH

MOV R5，#0AH ;三燈全滅

AJMP CHECK1

FLASH： CJNE A，#14H，CHECK1 ;下面系1s的情況，響并顯示號數并清R0，重新計

SETB RING

MOV R0，#00H

MOV R3，34H ;取回號數

MOV R5，#0BH

MOV R4，#0BH ;顯示FF和號數

AJMP CHECK1

CHECK1:JNB P1.7，QUIT1

ACALL DISPLAY

AJMP HERE

QUIT1： CLR RING

CLR OK

AJMP START

;=====單片機搶答器顯示程序=====

DISPLAY：

MOV DPTR，#DAT1 ;查表顯示程序，利用P0口做段選碼口輸出/P2低三位做位選碼輸出，

MOV A，R5

MOVC A，@A+DPTR

MOV P2，#01H

MOV P0，A

ACALL DELAY

MOV DPTR，#DAT2

MOV A，R4

MOVC A，@A+DPTR

MOV P2，#02H

MOV P0，A

ACALL DELAY

MOV A，R3

MOVC A，@A+DPTR

MOV P2，#04H

MOV P0，A

ACALL DELAY

RET

DAT1:DB 00H，06h，5bh，4fh，66h，6dh，7dh，07h，7fh，6fh，00H，71H

;“滅”，“1”，“2”，“3”，“4”，“5”，“6”，“7”，“8”，“9”，“滅”，“F”

DAT2:DB 3fh，06h，5bh，4fh，66h，6dh，7dh，07h，7fh，6fh，00H，71H

;第一個為零，其他與上相同，因為十位如果為零顯示熄滅

;====加減時間延時（起到不會按下就加N個數）======

DELAY1： MOV 35H，#08H

LOOP0： ACALL DISPLAY

DJNZ 35H，LOOP0

RET

;=====延時（顯示和去抖動用到）=====

DELAY： MOV 32H，#12H

LOOP： MOV 33H，#0AFH

LOOP1： DJNZ 33H，LOOP1

DJNZ 32H，LOOP

RET

;=====發聲程序=====

BARK： SETB RING

ACALL DELAY1

ACALL DELAY1

CLR RING ;按鍵發聲

RET

;=====TO溢出中斷（響鈴程序）=====

T0INT： MOV TH0，#0ECH

MOV TL0，#0FFH

JNB RING，OUT;

CPL P3.6 ;RING標志位為1時候P3.6口不短取反使喇叭發出一定頻率的聲音

OUT： RETI

;=====T1溢出中斷（計時程序）=====

T1INT： MOV TH1，#3CH

MOV TL1，#0B0H

INC R0

RETI

END